A Night at the Office #4

While the original plan for A Night at the Office was to focus on a conversation between Abigail and a single NPC, there were always a few supplementary characters who'd get more than just a quick mention. As my familiarity with Ren'Py grew, the scenes involving NPCs developed, to the point where I had a whole sequence - accessible by a particular route through the early part of the story - featuring one of two additional speaking NPCs, selected at random, per playthrough.

Simple as this addition is in the grand scheme of things, I'm rather proud of how it has worked out, and how I was able to figure out what needed doing with just a little research (and a nudge to adopt Ren'Py 8, from another user of the LemmaSoft forum).

Essentially, what I wanted to do was add a disposable character who would be either male or female. That's easy enough but, since I felt inclined to ensure the characters' pronouns were correct in the dialogue, that meant adding the necessary variables into the randomised selection.

init:
     default randomintern = []
     default intern_name="Intern"
     define intern_gender = ["male","female"]
     default their = "their"
     default they = "they"
     default them = "them"
     default themself = "themself"
label internselection: # this label is CALLed at a specific point in the story
     $ randomintern = renpy.random.choice(intern_gender)
     if randomintern == "female":
         $ their = "her"
         $ they = "she"
         $ them = "her"
         $ themself = "herself"
     else:
         $ their = "his"
         $ they = "he"
         $ them = "him"
         $ themself = "himself"
     return

Pretty sure I could simplify(?) further by setting up the pronouns in the same way I've set up intern_gender and then make used of them as [internpronoun[0]], internpronoun[1]], etc., but I wanted to keep everything clear and straightforward, so I wouldn't later forget what I was doing or which pronoun was which. I may well go back and alter this once I've got everything up and running properly, though.

There are only three variations of each gendered sprite - or, more specifically, just two poses - relaxed and tense - but one of them has two possible expressions - relaxed smile and nervous smile. Limited though they are, I wanted these two characters to be as dynamic as possible. The obvious thing was to add a blink frame but, for the tense pose/panicked expression, I asked the artist to leave the irises on a separate layer so I could make the sprite's eyes jitter nervously. Alongside his, I added a second blink pattern, which is both faster and features multiple blinks.

default intern_blink = renpy.random.randint(4,12)
default intern_panicblink = renpy.random.randint(2,7)
init python:
     def intblinky(trans,st,at):
         global intern_blink
         if st >= intern_blink:
             intern_blink = renpy.random.randint(4,12)
             return None
         else:
             return 0
      def intpanic(trans,st,at):
         global intern_panicblink
         if st >= intern_panicblink:
             intern_panicblink = renpy.random.randint(2,7)
             return None
         else:
             return 0

The iris jitter was accomplished via what is possibly the most inelegant bit of coding I've ever produced, moving them, at random, very slightly in one of eight directions, then moving them straight back:

image kristine_irisjitter:
     contains:
         "images/intern/kristine panic_eyesblank.png"
     contains:
         "images/intern/kristine panic_irises.png"
         subpixel True
         choice:
             0.1
             xoffset -0.3 yoffset -0.3
             0.1
             xoffset 0.3 yoffset 0.3
         choice:
             0.1
             xoffset 0 yoffset -0.3
             0.1
             xoffset 0 yoffset 0.3
         choice:
             0.1
             xoffset 0.3 yoffset -0.3
             0.1
             xoffset -0.3 yoffset 0.3
         choice:
             0.1
             xoffset -0.3 yoffset 0
             0.1
             xoffset 0.3 yoffset 0
         choice:
             0.1
             xoffset 0.3 yoffset 0
             0.1
             xoffset -0.3 yoffset 0
         choice:
             0.1
             xoffset -0.3 yoffset 0.3
             0.1
             xoffset 0.3 yoffset -0.3
         choice:
             0.1
             xoffset 0 yoffset 0.3
             0.1
             xoffset 0 yoffset -0.3
         choice:
             0.1
             xoffset 0.3 yoffset 0.3
             0.1
             xoffset -0.3 yoffset -0.3
         repeat

While the eye jitter needed some fine-tuning (for some reason, setting it as 1 pixel in any direction looked like it was moving at least 2 pixels in each direction, so I ended up dropping to 0.3 pixels with subpixel movement activated), it worked remarkable well... So I'm very much on-track, with one of the two intern characters now present and functioning as expected in the current build of the demo.

Then, this and the random blinking are incorporated into the character sprite variations, thus:

image kristineblinkingtense: # standard blink speed for the tense expression
     "images/intern/kristine nervsmile_eyesopen.png"
     function intblinky
     "images/intern/kristine nervsmile_blink.png"
     pause 0.1
     repeat
image kristineblinkingrelaxed: # standard blink speed for the relaxed expression
     "images/intern/kristine relaxsmile_eyesopen.png"
     function intblinky
     "images/intern/kristine relaxsmile_blink.png"
     pause 0.1
     repeat
image kristineblinkingscared: # increased blink speed + jittering eyes
     "kristine_irisjitter"
     function intpanic
     choice:
         "images/intern/kristine panic_blink.png"
         pause 0.1
         "kristine_irisjitter"
         pause 0.2
         repeat 2
     choice:
         "images/intern/kristine panic_blink.png"
         pause 0.1
         "kristine_irisjitter"
         pause 0.2
         repeat 3
     repeat
image kristine nervous: # relaxed pose with nervous smile, blinking normally
     contains:
         "images/intern/kristine nervsmile.png"
     contains:
         "kristineblinkingtense"
image kristine relaxed: # relaxed pose with relaxed smile, blinking normally
     contains:
         "images/intern/kristine relaxsmile.png"
     contains:
         "kristineblinkingrelaxed"
image kristine panicking: # tense pose with panicked expression, jittering eyes and rapid blinking
     contains:
         "images/intern/kristine panic.png"
     contains:
         "kristineblinkingscared"

The artist only took 2 weeks to deliver the sprite, too... and that, with impending deadlines with other clients! Substantially better service than the artist I used previously. With just a few little animation tricks, this simple new sprite feels every bit as 'alive' as Abigail. I was a little concerned, initially, that I'd made a mistake in asking for the sprite to be drawn face-on rather than at an angle, like Abigail, but it really doesn't look half as out of place as I'd feared.

As I write, the sprite is currently saved 1:1 - just under 700px tall, in a 1280x720 pixel project - but, since there's a point where the sprite is displayed zoomed in, I will probably go back and resave the components at a larger size, then scale down within Ren'Py. It was drawn substantially oversize (more than 5000px tall!), so there's plenty to work with. Might leave that till after I have the male variant as well, though.